Setting up wifi hotspot with connectify.

[steftymo 0]

I'm using a Dell xps13 Windows 10 laptop and am trying to get a hotspot working via connectify. I have airvpn running and am connected to a server in Netherlands.

Problem is connectify doesn't recognise this as an "internet to share" in the pull down box. It shows my main wifi and TAP Windows Adapter v9. But this isn't sending my vpn internet to the hotspot.

Any ideas please?

[OpenSourcerer 1359]

Share a VPN connection from your Windows (manual)

 

I can also provide a simple Batch script (semi-automated).

[mooseamoose 0]

I am interested in your batch script. Thanks!

[OpenSourcerer 1359]

@echo off
set started=0
set ssid=ssidhere
set psk=1234567890
goto intro

:intro
echo USAGE: start 1, stop 2, exit 3. Anything else prints status.
set /p i=
if %i%==1 goto startcheck
if %i%==2 goto stop
if %i%==3 goto exit
goto status

:status
if %started%==1 (echo INFO: Hosted network is started.) else echo INFO: Hosted network is not started.
goto intro

:startcheck
if %started%==0 goto start
if %started%==1 echo ERROR: Already started by this script. Not starting it again.
goto intro

:start
echo INFO: Allowing the hosted network
netsh wlan set hostednetwork mode=allow
echo INFO: Setting SSID and PSK to %ssid% : %psk%
netsh wlan set hostednetwork ssid=%ssid% key=%psk% keyUsage=persistent
echo INFO: Trying to start the hosted network
netsh wlan start hostednetwork
set started=1
goto intro

:stop
if %started%==0 echo INFO: This script didn't start anything.
echo INFO: Stopping whatever is running now
netsh wlan stop hostednetwork
echo INFO: Disallowing the hosted network
netsh wlan set hostednetwork mode=disallow
set started=0
goto intro

:exit
if %started%==1 (echo ERROR: This script started the hosted network! Stop it first.) else exit
goto intro

Follow the instructions on the website I linked to to set the shared interface. I believe it's possible to do this on cmd as well but as a Linux user I am not going to spend time to figure that out.